ION TRAP Quantum Computers

In order to build a quantum computer we need something that can serve as a qubit. It should behave as a quantum mechanical system but be scalable. Several candidates for possible quantum computer applications have been advanced. They include

Ion - trap quantum computing (Cirac-Zoller protocol)
NMR (Nulcear Magnetic Resonance)  quantum computers 
Adiabatic quantum computing - Dwave
Photonic quantum computers 
Cavity QED quantum computers etc.


We shall discuss the Cirac-Zoller scheme which treats a trapped atomic ion as the fundamental qubit.

A working quantum computer should allow individual qubits to be individually addressed, allow two or more qubits to "talk" to
each other (in order to built gates), and be scalable. The ion-trap quantum computer has already met these three criteria.

The linear rf-ion trap

You may remember from your physics 181 that the electric potential of a cylinder, held at a constant potential (Subscript[V, 0]) has the form

V(x,y) = (Subscript[V, 0]) + λ Log((R/ρ))  for ρ > R
           = (Subscript[V, 0])  for ρ ⩽ R

where ρ=(Sqrt[(x^2)+(y^2)])  is the distance from the axis along the center of the cylinder, R is th radius of  the cylinder and λ is a constant . Lets make a 3D  plot of this  potential.

V0=2;
v[x_,y_,x0_,y0_,R0_]:=Which[ Sqrt[(x-x0)^2+(y-y0)^2]>R0,V0+Log[R0/Sqrt[(x-x0)^2+(y-y0)^2]] ,Sqrt[(x-x0)^2+(y-y0)^2]<=R0,V0]

Plot3D[v[x,y,0,0,0.5],{x,-10,10},{y,-10,10},PlotPoints->100,PlotRange->All]

dipole[x_,y_]:=v[x,y,0,2,0.5]-v[x,y,0,-2,0.5]

Plot3D[dipole[x,y],{x,-10,10},{y,-10,10},PlotPoints->100,PlotRange->All]

quadrupole[x_,y_]:=v[x,y,0,2,0.5]-v[x,y,-2,0,0.5]+v[x,y,0,-2,0.5]-v[x,y,2,0,0.5]

Plot3D[quadrupole[x,y],{x,-4,4},{y,-4,4},PlotPoints->100,PlotRange->All]

A more care full analysis shows that near the origin the potential has the form

V(x,y) = (Subscript[V, 0 ]) ((x^2)-(y^2)) (Subscript[Φ, 0])/2  where (Subscript[Φ, 0]) is a constant.

Vquad[x_,y_]=V0(x^2-y^2)

Plot3D[Vquad[x,y],{x,-4,4},{y,-4,4}]

Now, instead of a constant voltage (Subscript[V, 0 ]) on the electrodes, we can change the polarity in a time-dependent way, lets consider
a Cos[ω t] dependence so that now the potential at the origin looks like,

V(x,y) = (Subscript[V, 0 ]) Cos(ω t) ((x^2)-(y^2)) (Subscript[Φ, 0])/2

Vquad[x_,y_,t_]=V0 Cos[ω t](x^2-y^2) /. ω->2Pi

Manipulate[Plot3D[Vquad[x,y,t],{x,-4,4},{y,-4,4},PlotRange->{-30,30}],{t,0,2}]

So how does a charged particle behave under the influence of such a "rotating saddle" potential ? 
The force that a particle experiences is the negative of the gradient of the potential times its charge q
i.e.
(Subscript[F , x]) =  -q  x  (Subscript[V, 0 ]) Cos(ω t) 
(Subscript[F , y]) =   q  y  (Subscript[V, 0 ]) Cos(ω t) 

and Newton's equation of motion are

m (Overscript[x, ..]) =  -q  x  (Subscript[V, 0 ]) Cos(ω t) 
m (Overscript[y, ..]) =   q  y  (Subscript[V, 0 ]) Cos(ω t)

eq1=x''[t]==- q/m  x[t]Cos[ω t]  /.{q->1,m->1,ω->2Pi}
eq2=y''[t]==  q/m  y[t]Cos[ω t]  /.{q->1,m->1,ω->2Pi}

(* initial conditions *)

x0=2.0;
y0=-1.0;
v0x=1.0;
v0y=1.0;

tend=10;
sols=Flatten[NDSolve[{eq1,eq2,x[0]==x0,y[0]==y0,x'[0]==v0x,y'[0]==v0y},{x[t],y[t]},{t,0,tend}]];
fig1=ParametricPlot[Evaluate[{x[t],y[t]}/.sols],{t,0,tend},PlotRange->All]

Analytic studies of the above equations show that the dynamics can be described by two types of motion, one is called
a micromotion and is evidenced above by the rapidly oscillating wiggles in the overall motion. More important is the overall
average motion that is described by a simple 2D harmonic oscillator potential that has the form

V(x,y) = 1/2 m ((Ω )^2)( (x^2)+ (y^2)) 

Ω= ((q (Subscript[Φ, 0]) )/(m ω (Sqrt[2])))

this potential "binds" the system to the vicinity of the origin.  We can analytically solve such a 2 D system, the result
is

x(t)= (Subscript[A, x]) Cos(Ω t + (Subscript[ϕ, x]))
y(t)=(Subscript[A, y]) Cos(Ω t + (Subscript[ϕ, y]))

where the quantities  (Subscript[A, x]) (Subscript[A, y]) (Subscript[ϕ, x]) (Subscript[ϕ, y]) are related to the initial conditions of the ions motion

x(0)=  (Subscript[x, 0]) = (Subscript[A, x]) Cos( (Subscript[ϕ, x]))
y(0)=  (Subscript[y, 0]) = (Subscript[A, y]) Cos( (Subscript[ϕ, y]))

and  (Subscript[v, x])(0) =  (Subscript[v, ox]) = - Ω (Subscript[A, x]) Sin((Subscript[ϕ, x]))  (Subscript[v, y])(0)= (Subscript[v, oy]) = - Ω (Subscript[A, y]) Sin((Subscript[ϕ, y]))  and so   tan((Subscript[ϕ, x]))  = - (Subscript[v, ox]) / Ω (Subscript[x, 0]) 
                                                                                                                tan((Subscript[ϕ, y]))  = - (Subscript[v, oy]) / Ω (Subscript[y, 0]) 
                                                                                                                (Subscript[A, x]) = (Subscript[x, 0])/Cos((Subscript[ϕ, x]))
                                                                                                                (Subscript[A, y]) = (Subscript[y, 0])/Cos((Subscript[ϕ, x]))

Omega= q/m/ω/Sqrt[2] /. {q->1,m->1,ω->2 Pi};
phix=ArcTan[-v0x/x0/Omega];
phiy=ArcTan[-v0y/y0/Omega];
Ax=x0/Cos[phix];
Ay=y0/Cos[phiy];

xmotion[t_]=Ax Cos[Omega t +phix];
ymotion[t_]= Ay Cos[Omega t +phiy];

ion[t_]:=Show[fig1,Graphics[{PointSize[0.05],Point[{xmotion[t],ymotion[t]}]}],PlotRange->{{-1.1Ax,1.1Ax},{-1.1Ay,1.1Ay}},Axes->True]

fig2=Manipulate[ion[t],{t,0,2Pi/Omega}]

Hyperlink["http://www.youtube.com/watch?v=XTJznUkAmIY"]
Hyperlink["http://www.youtube.com/watch?v=bkYXNeJ8IP0"]
Hyperlink["http://www.youtube.com/watch?v=PYpbKSmOnNc"]

Laser cooling

When we load ions into this trap they are confined along the axis of the trap but, as shown above, they can execute harmonic
motion in the xy plane. Our goal is to align ions along the axis and minimize xy motion as much as possible. from the above 
example we see that we can do this by making (Subscript[v, ox]),  (Subscript[v, oy]) as small as possible. Since velocity can be related to kinetic energy, which in turn,
can be characterized by a temperature, the process of minimizing the kinetic energy of the trapped ion is called cooling. A powerfull
method for accomplishing this is called laser cooling.

Atoms and ions have internal structure, they are called energy levels and in an oversimplistic description we can consider our
ions to have two energy levels as shown in the picture below

Roughly speaking the ion absorbs a photon with energy  ℏω  that is equal to the difference in the energies of the two 
levels of the ion. Here ℏ is Plank's constant and ω is the angular frequency of the photon which is related to its wavelength λ by
the relation ω = 2 π c/λ where c is the speed of light. In addition to absorbing the energy of the photon the ion can also "gain" a momentum kick from that photon. This momentum is a vector and is given by the expression