!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!  Program file name: dart2.f90                                           !
!                                                                         !
!  © Tao Pang 2006                                                        !
!                                                                         !
!  Last modified: November 13, 2009                                       !
!                                                                         !
!  (1) This F90 program is created for the book, "An Introduction to      !
!      Computational Physics, 2nd Edition," written by Tao Pang and       !
!      published by Cambridge University Press on January 19, 2006.       !
!                                                                         !
!  (2) No warranties, express or implied, are made for this program.      !
!                                                                         !
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
MODULE CSEED
  INTEGER*8 :: SEED
END MODULE CSEED
!
PROGRAM DART2
!
! An example of evaluating pi by throwing a dart to a
! unit square with 0<x<1 and 0<y<1 with a long period
! unform random number generator.
!
  USE CSEED
! IMPLICIT NONE
  INTEGER*8 :: TWO=2
  INTEGER, PARAMETER :: N=1000000
  INTEGER :: I, IC
  INTEGER, DIMENSION (8) :: T
  REAL :: X, Y, RANF
!
! Initiate the seed from the current date and time
!
        CALL DATE_AND_TIME(VALUES = T)
        SEED = T(1)+70*(T(2)+12*(T(3)+31*(T(5)+23*(T(6)+59*T(7)))))
        IF (MOD(SEED,TWO).EQ.0) SEED = SEED-1
!
  IC = 0
  DO I = 1, N
    X = RANF()
    Y = RANF()
    IF ((X*X+Y*Y) .LT. 1) IC = IC + 1
  END DO
  WRITE(6, *) "Estimated pi: ", 4.0*IC/N 
END PROGRAM DART2
!
FUNCTION RANF() RESULT (CR)
!
! Function to generate a uniform random number in [0,1]
! following x(i+1)=a*x(i) mod c with a=7**5 and
! c=2**63-1.  Here the seed is a global variable.
!
  USE CSEED
  IMPLICIT NONE
  INTEGER*8 :: H, L, T, A, C, Q, R
  DATA A/16807/, C/9223372036854775807/, Q/548781581296767/, R/12838/
  REAL :: CR
!
  H = SEED/Q
  L = MOD(SEED, Q)
  T = A*L - R*H
  IF (T .GT. 0) THEN
    SEED = T
  ELSE
    SEED = C + T
  END IF
  CR = C
  CR = SEED/CR
END FUNCTION RANF